En un artículo anterior publiqué una Agenda Calendario Lunar que se puede descargar desde aquí:
También he publicado la primera parte de la explicación de:
Cómo funciona la Agenda Calendario Lunar (1/2) | #ExcelPedroWave
En este artículo explico cómo funciona todo lo demás para que esta Agenda Calendario Lunar pueda verse también en inglés:
Para ello, igual tienes que abrir este artículo en un navegador de incógnito, para que no convierta los días y meses a tu configuración regional en la nube y puedas verlo en inglés...
Agenda Calendario Lunar en la nube
Como esta Agenda Calendario Lunar está diseñada con fórmulas, sin macros VBA, se puede incrustar en este blog y probarla en la nube de Microsoft OneDrive. Te propongo que también la incrustes en tu blog para ayudarme a promocionarla:
ATENCIÓN: Hay un botón de descarga en esta Agenda Calendario Lunar en la nube. Es necesario descargarla para guardar tus datos, o copiarla en tu Microsoft OneDrive, ya que en la nube no se guardarán los cambios que hagas...
Cómo funcionan los Aniversarios
Los aniversarios se deben editar en la hoja Aniversarios, escribiendo la fecha y el tipo de aniversario.
La fecha es la del comienzo del aniversario, escribiendo la fecha de nacimiento, de defunción, de boda, o de cualquier otro aniversario que se quiera recordar.
La columna C es informativa con el número de años transcurridos y se calcula con la función SIFECHA. Por ejemplo, en la celda C4 con una fórmula de este tipo:
=SI(O(A4="";A4>Fecha_Hoy);"";SIFECHA(A4;Fecha_Hoy;"y"))
En la hoja oculta 'Fechas - Dates' he incluido la tabla TablaEventos con las fechas y eventos que se mostrarán en la hoja Agenda.
La TablaEventos, en el rango C3:G65, contiene hasta 62 fechas de la Agenda, comenzando por el día de hoy.
En el rango D4:D65, se muestran los festivos y aniversarios con fórmulas del tipo:
=SI.ERROR(INDICE(INDIRECTO("'" & AÑO($C4) & "'!B:B");$G4) & "";"")
que buscan en la columna B de la hoja del año, por defecto 2022, los festivos y aniversarios, que se indican anteponiendo "A." al aniversario.
En la columna E hay una megafórmula para encontrar todos los eventos de las 24 horas de un día:
=SI.ERROR(ESPACIOS(INDICE(INDIRECTO("'" & AÑO($C4) & "'!B:B");$G4)&" "&SI(INDICE(INDIRECTO("'" & AÑO($C4) & "'!C:C");$G4)=0;"";"0h " & INDICE(INDIRECTO("'" & AÑO($C4) & "'!C:C");$G4)&" ")&
que continua para cada una de las 24 horas del día, usando la función INDIRECTO para referenciar a las columnas de cada hora, por lo que al ser demasiado larga no la transcribo aquí...
En las columnas F y G también se calculan la columna y la fila del primer evento de un día con fórmulas del tipo:
Col: =SI.ERROR(SUSTITUIR(DIRECCION(1;COINCIDIR(VERDADERO;INDIRECTO(AÑO($C4) & "!B" & $G4 & ":Z" & $G4)<>"";0)+1;4);"1";"");"A")
Fila: =$C4 - FECHA(AÑO($C4);1;1) + 2
La columna oculta D de la hoja Agenda permite saber qué eventos de la Agenda se van a mostrar, pues calcula las filas que tienen algún evento en la TablaEventos con la fórmula matricial:
{=SI.ERROR(K.ESIMO.MENOR(SI((TablaEventos[Fecha]>=Fecha_Hoy)*(TablaEventos[Agenda]<>"");FILA('Fechas - Dates'!$C$4:$C$65)-MIN(FILA('Fechas - Dates'!$C$4:$C$65))+1;"");FILA()-FILA(D3));0)}
Para insertar esta fórmula matricial se selecciona el rango D4:D28, se escribe la fórmula sin corchetes y se presionan simultáneamente las teclas: Control + Mayúsc + Intro
Con la función INDICE se construyen las fórmulas de las columnas A:C y no voy a explicarlas aquí.
Los formatos condicionales de la hoja Agenda permiten colorear los eventos, festivos, aniversarios, sábados, domingos y el día de hoy, mediante estas fórmulas:
La hoja Diario contiene dos columnas auxiliares ocultas, la C y la D.
En la celda C3 se define el nombre Horas_Fila: =$B3 - FECHA(AÑO($B3);1;1) + 2, con la fila de la hoja del año que corresponde al día seleccionado en el desplegable de la celda B3.
En la celda D3 se define el nombre Horas_Hoja: ="[" & Archivo_Nombre & "]'" & AÑO(Horas_Fecha) & "'!", con el nombre del archivo y la hoja del año.
En el rango B4:B28 se han escrito las títulos de las columnas de la hoja con el año.
En el rango C4:C28 se han escrito las letras que corresponden a las columnas de la hoja con el año.
En el rango B4:C28 hay fórmulas con la función HIPERVINCULO para ir a las celdas de la hoja del año, por defecto 2022.
Los formatos condicionales de la hoja Diario permiten colorear los eventos, festivos, aniversarios, sábados, domingos y el día de hoy, mediante estas fórmulas:
En la celda B5 de la hoja Calendario se define el nombre Fecha1_Mes, con la fórmula:
=Fecha_Comienzo+1-DIASEM(Fecha_Comienzo;SI(ESNUMERO(Semana_Comienzo);DIASEM(Semana_Comienzo);3-COINCIDIR(Semana_Comienzo;TEXTO(Semana_Comienzo_Lista;"dddd");0)))
que depende de:
Fecha_Comienzo: ='Fechas - Dates'!$O$1, con el día 1 del mes y año elegidos.
Semana_Comienzo: ='Calendario - Calendar'!$B$3, donde se indica si la semana comenzará en lunes o domingo, definido con el nombre: Semana_Comienzo_Lista
Además, la hoja Calendario se basa en la hoja oculta 'Fechas - Dates', en la que he incluido la TablaCalendarioAgenda con las fechas y eventos que se mostrarán en la hoja Calendario.
La TablaCalendarioAgenda, en el rango I3:M65, contiene hasta 62 fechas, comenzando por el primer día del mes y año seleccionado en la hoja Calendario, que se calcula en la celda 'Fechas - Dates'!O1 como:
Fecha_Comienzo: =FECHA(Año_Número;SI(ESNUMERO(Mes_Número);MES(Mes_Número);COINCIDIR(Mes_Número;TEXTO(Meses_Lista;"mmmm");0));1)
En el rango J4:J65 hay fórmulas para mostrar los festivos y aniversarios.
En el rango K4:K65 hay fórmulas para mostrar los eventos del calendario.
Las columnas auxiliares L y M calculan la columna y fila del primer evento.
Como ejemplo sirva la imagen de arriba. En las celdas combinadas 'Calendario - Calendar'!E18:V18 se usa la fórmula:
=SI(MES(B18)=MES(Fecha_Comienzo);HIPERVINCULO("[" & Archivo_Nombre & "]" & Año_Número & "!" & INDICE(TablaCalendarioAgenda[Col];COINCIDIR(B18;TablaCalendarioAgenda[Fecha])) & B18 - FECHA(Año_Número;1;1) +2; INDICE(TablaCalendarioAgenda[Agenda];COINCIDIR(B18;TablaCalendarioAgenda[Fecha])) & "… ");"")
para obtener los eventos del día que se ha elegido en la celda B18 y se establece un hipervínculo a la celda correspondiente al primer evento de ese día de la hoja del año, por defecto 2022.
El mismo tipo de fórmula se usa en las celdas similares, comenzando por la celda combinada en B6:D6.
Los formatos condicionales de la hoja Diario permiten colorear los eventos, festivos, aniversarios, sábados, domingos y el día de hoy, mediante estas fórmulas:
Para calcular las fases lunares que se ven en la hoja Calendario ha hecho falta una hoja auxiliar oculta 'Fases Lunares - Moon Phases' que contiene dos tablas:
Los datos de la TablaLunar de la izquierda los extraje de la página:
que contiene las fases lunares de los años 2001 a 2100, con la ayuda de un archivo que me permite hacer la extracción, transformación y carga (ETL en inglés) de las fases lunares con una conexión a la página comentada:
Esta plantilla no contiene macros y todo el cálculo se realiza ¡sólo con fórmulas!
Si quieres saber la contraseña que desprotege las hojas, tendrás que visitar la siguiente página con la primera versión de una Agenda Calendario Lunar que hice hace unos 4 años:
Gracias por leer hasta aquí y espero que esta Agenda Calendario Lunar sea útil por muchos años...
No Response to "Cómo funciona la Agenda Calendario Lunar (2/2)"
Leave A Reply
Dime si te gusta lo que lees y, si no te gusta, dime por qué. Tengo habilitada la moderación de comentarios. Tu comentario se publicará pronto.