Comparador interactivo con gráficos escalonados

Posted on junio 22, 2022 by Excel Pedro Wave

Voy a añadir interactividad al comparador que publiqué aquí:

Comparador PVPC electricidad | #ExcelPedroWave

Así podremos comparar los nuevos precios regulados de la luz en España (PVPC), que se ven reducidos por aplicar un tope al gas al resto de energías con las que se genera la energía eléctrica. El tope al gas será de 40 €/MWh durante los próximos 6 meses. De todos modos, la primera semana de aplicación del tope al gas la factura eléctrica ha seguido siendo muy cara debido a la ola de calor, como se comprueba con el comparador que se puede descargar al final de este artículo.

Para comparar más de dos días es mejor añadir una segmentación de datos con los días a comparar, así se puede elegir qué días comparar y ver los datos de uno o varios días.

La interactividad del gráfico se consigue mediante la intervención de una macro y estas dos segmentaciones de datos:

Con una segmentación de datos se eligen las fechas sobre la tabla de fechas.
Con otra segmentación de datos se elige el valor mínimo del eje vertical, que dependerá de los valores PVPC de las fechas elegidas.

Cómo diseñé este comparador interactivo

Los datos están en la tabla "TablaEscalones" con los valores PVPC de las 24 horas de 7 días.

Se ha elegido el 14/06 por ser el último día en que se calculó el PVPC sin el tope al gas para calcular la tarifa eléctrica regulada en España y los 6 días siguientes para comparar el PVPC en la primera semana de aplicación de los precios en la nueva "isla energética" de la península ibérica.

Se calcula el promedio, el máximo y el mínimo de cada día y esta tabla es el origen del gráfico escalonado, con la leyenda de cada serie con el promedio de cada día entre paréntesis.

La tabla "TablaFechas", en el rango A31:B39, contiene las 7 fechas y el valor mínimo PVPC de cada día. Se filtra con la segmentación de datos de fechas.

En la columna A se calculan las fechas con la fórmula:

=FECHANUMERO(TablaEscalones[[#Encabezados];[14/06]])

En la columna B se calculan los mínimos con la fórmula: =B28, cambiando la columna en las siguientes fechas.

En la celda D42, con el nombre definido: miPVPCmín, se calcula con la fórmula:

=REDONDEAR.MENOS(SUBTOTALES(105;TablaFechas[Mínimo])/50;0)*50

Con lo que se consigue el valor mínimo del eje vertical para la tabla de fechas filtrada.

La tabla "TablaMínEjeVertical" está en el rango A42:A50, con los valores mínimos posibles del eje vertical, siendo la fórmula de la celda A43: =miPVPCmín

La celda A44 con la fórmula: =SI(A43=0;0;A43-50) se arrastra hasta la celda A49.

En la celda A50 se calcula el máximo con la fórmula: =SUBTOTALES(104;[Mín. eje])

Esta tabla se filtra con su propia segmentación de datos para el valor mínimo del eje vertical.

Esta es una imagen animada con el efecto de cambiar el valor mínimo del eje vertical:

Macros del comparador interactivo

Para conseguir la interactividad de este comparador con gráficos escalonados hacen falta algunas macros. Como la interactividad se consigue al seleccionar fechas o valores mínimos del eje vertical en las segmentaciones de datos, hay que conseguir que esos cambios sean actualizados en el gráfico, para lo que hace falta responder al evento que se entera del cambio.

Ese evento es Worksheet_Calculate, dentro de la hoja 'PVPC', que llama a la macro: FiltrarSeriesPVPC, que comprueba si el cambio ha sido en la segmentación de las fechas o en la segmentación del valor mínimo del eje vertical.

Private Sub Worksheet_Calculate()
'
' Evento Worksheet_Calculate
'
    ' Filtra las series PVPC
    FiltrarSeriesPVPC
    
End Sub

Si ha cambiado la selección de la segmentación de fechas, filtra las series del gráfico en las que la altura de las fechas es cero en la tabla de fechas, por estar filtradas.

Si ha cambiado la segmentación del valor mínimo del eje vertical, lo cambia en el gráfico.

Sub FiltrarSeriesPVPC()
'
' Filtrar las series con 7 días en el gráfico PVPC,
' manteniendo el valor mínimo seleccionado para el eje vertical.
' Actualiza el cambio del valor mínimo del eje vertical.
'
    Dim iSerie As Integer
    Dim iMín As Integer
    Dim bFiltrada As Boolean
    Dim bFechas As Boolean
    Dim lFila As Long
    
    ' Fila de la tabla de fechas
    lFila = Range("RangoFechas").Row
    
    With Worksheets("PVPC").ChartObjects("Gráfico Escalonado Columnas").Chart
        
        ' Bucle para recorrer las 7 series
        For iSerie = 1 To 7
        
            ' Filtra las series con altura 0 de las fechas
            bFiltrada = Worksheets("PVPC").Cells(lFila + iSerie, 1).Height = 0
            If .FullSeriesCollection(iSerie).IsFiltered <> bFiltrada Then
                .FullSeriesCollection(iSerie).IsFiltered = bFiltrada
                bFechas = True
            End If
        Next iSerie
        
        ' Cambia el valor mínimo del eje vertical
        If bFechas Then
            iMín = ObtenerMínEjeVertical
            If iMín = -1 Then
                iMín = Range("miEjeVmín").Value2
            ElseIf iMín > Range("miPVPCmín").Value2 Then
                iMín = Range("miPVPCmín").Value2
            End If
        Else
            iMín = Range("miEjeVmín").Value2
        End If
        .Axes(xlValue).MinimumScale = iMín
    
    End With
    
End Sub

Con la función ObtenerMínEjeVertical se obtiene el valor seleccionado en la segmentación de datos con el mínimo valor del eje vertical del gráfico.

Function ObtenerMínEjeVertical() As Double
'
' Obtener el valor mínimo del eje vertical
'
    Dim ii As Integer
    
    ObtenerMínEjeVertical = -1
    With ActiveWorkbook.SlicerCaches("SegmentaciónDeDatos_Valor_vertical")
        For ii = 1 To .SlicerItems.Count
            If .SlicerItems(ii).Selected Then
                ObtenerMínEjeVertical = .SlicerItems(ii).Value
                Exit For
            End If
        Next ii
    End With
    
End Function

Descarga del comparador interactivo

Puedes descargar este comparador interactivo v2.0 desde estos enlaces:

Microsoft OneDrive: Comparador PVPC PW2.xlsm

Sites Google Drive: Comparador PVPC PW2.xlsm

Abre la plantilla con una versión de Excel de escritorio a partir de Excel 2013 y presiona el botón: Habilitar edición

Aparece una ADVERTENCIA DE SEGURIDAD: Las macros se han deshabilitado. Presiona el botón: Habilitar contenido

Esta plantilla contiene macros y no está protegida, por lo que se pueden estudiar y analizar las fórmulas y el código VBA.

Y con este artículo finaliza la serie dedicada al PVPC, con el que se confecciona la factura de la energía eléctrica española. Enlace a los artículos PVPC:

Resultados de la búsqueda de PVPC | #ExcelPedroWave

De paso me he atrevido a contribuir en estos dos artículos de Wikipedia:

Gracias por seguir leyendo este blog.

2 Response to "Comparador interactivo con gráficos escalonados"

Anónimo Says....

23 junio, 2022 21:37

en mi pais el consumo es mensual, puedo modificar para ver el consumo mensual?

Excel Pedro Wave Says....

24 junio, 2022 08:38

Anónimo, para aclarar: en cualquier parte del mundo el consumo de electricidad es instantáneo, a cualquier hora del día o de la noche para cualquier consumidor de luz que conecte equipos eléctricos a la red eléctrica. El consumo total de la factura eléctrica normalmente se calcula mensualmente o bimensualmente.

Este comparador no compara consumos si no precios horarios de varios días, aunque se puede adaptar, con un poco de habilidad, para comparar los consumos mensuales de varios años. ¿Es eso lo que quieres?

Comenta este artículo, critícalo o avisa si detectas algún error que haya que corregir.

#ExcelPedroWave

Traducir el blog