🔝To translate this blog post to your language, select it in the top left Google box.
Este bingo se me ocurrió mientras estaba diseñando los bingos de los dos artículos anteriores.
Ninguno de los bingos anteriores funciona ya, debido a que Microsoft se ha esmerado en corregir demasiado pronto el excelente BUG que permitió, durante unos meses, que las funciones volátiles dejaran de ser volátiles, tanto en Excel para Microsoft 365 como en Excel para la Web.
Por lo que he tenido que recurrir al viejo truco de usar el cálculo iterativo para diseñar mi bingo iterativo, y poder jugar con las nuevas actualizaciones del canal actual de Excel para Microsoft 365 y en Excel para la Web.
Este es el aspecto de mi bingo iterativo en Excel para Microsoft 365.
Este juego de bingo iterativo en Excel contiene 3 hojas:
Si aún no tienes una suscripción de pago a Microsoft 365, puedes probar gratuitamente mi bingo iterativo en la nube de Microsoft OneDrive.
Para marcar las casillas hay un desplegable para elegir entre VERDADERO (casilla marcada) y FALSO (casilla desmarcada).
Para ajustar el zoom en la nube:
Descarga este juego de bingo, probado en Excel para Microsoft 365, desde este enlace:
Abre el archivo y presiona el botón: Habilitar edición cuando aparezca el aviso de VISTA PROTEGIDA.
Las hojas están protegidas sin contraseña para que sea fácil analizar las fórmulas.
ATENCIÓN: Se puede modificar este libro de Excel respetando esta licencia:
Creative Commons — Atribución-NoComercial-CompartirIgual-No portada — CC BY-NC-SA 4.0
1) Marcar las casillas del cartón o de los cartones que quieras jugar
2) Marcar la casilla para Extraer las bolas
3) Extraer las bolas presionando:
- En Excel para la Web con el botón de abajo: Actualizar todas las conexiones de datos
- En Excel para Microsoft 365 con la tecla F9 repetidamente
4) Cantar línea, dos líneas o ¡Bingo!
5) Comenzar un nuevo juego, desmarcando la casilla: Extraer
En este vídeo explico cómo jugar a este bingo iterativo.
Para que no existan referencias circulares en las fórmulas de algunas celdas, que se llaman a sí mismas, hace falta tener habilitado el cálculo iterativo.
Aunque por defecto ya está habilitado el cálculo iterativo en el libro con este juego del bingo, no está de más saber cómo cambiar las opciones de cálculo.
Entrar en el menú: Archivo
Abajo hay un botón: Más...
con más opciones.
Seleccionar: Opciones
Y se abre la ventana: Opciones de Excel
Seleccionar: Fórmulas
En Opciones de cálculo:
Cálculo del libro: Automático
Está marcado: Habilitar cálculo iterativo
Iteraciones máximas: 1
Cambio máximo: 1
Con lo que cada recálculo de fórmulas iterativas se hará una vez y se cambiará en una unidad.
En el menú: Fórmulas > Administrador de nombres, hay 5 nombres definidos:
BolaExtraer: =BINGO!$S$2
BolaNúmero: =BINGO!$Q$2
BolaValor: =BINGO!$P$6
misBolas: =SI(BolaNúmero=0;"";BOLAS!$A$2:INDICE(BOLAS!$A$2#;BolaNúmero))
misCartones: =CARTONES!$AB$6:$AJ$23
La hoja 'BOLAS' solamente contiene una fórmula matricial iterativa en la celda A2:
=SI(BolaExtraer;$A$2#;ORDENARPOR(SECUENCIA(90);MATRIZALEAT(90)))
Si el valor de la celda BolaExtraer es:
La hoja 'CARTONES' genera los números de bolas de 6 cartones, que es un límite que me he impuesto por necesidades didácticas, y que se puede ampliar si se tiene un nivel intermedio de Excel.
En el bingo de 90 bolas, cada uno de los cartones tiene 3 líneas de 5 bolas cada una, con 4 espacios sin números en cada fila.
AVISO: En cualquiera de los bingos que he diseñado las bolas no se repiten en ninguno de los 6 cartones generados en cada juego.
Los números de bola mínimos de cada columna de cada cartón, están escritos en el rango B5:J5.
Los números de bola aleatorios de cada columna de cada cartón, están en el rango B6:J6 con unas fórmulas iterativas matriciales dinámicas, que se desbordan en las siguientes filas. Por ejemplo, para generar números aleatorios únicos del 1 al 9, la fórmula de la celda B6 es:
=SI(BolaExtraer;B$6#;ORDENARPOR(SECUENCIA(9;1;B$5);MATRIZALEAT(9)))
Para cambiar aleatoriamente el orden de los cartones en cada juego, se hace con la fórmula en la celda M6:
=SI(BolaExtraer;$M$6#;ORDENARPOR(SECUENCIA(6);MATRIZALEAT(6)))
Las filas de cada cartón se calculan en el rango N6:N11 con la fórmula en N6 arrastrada hacia abajo:
=3*(M6-1)
Los patrones de los 6 cartones, con un 1 si hay número de bola, y un 0 si no hay número de bola, están escritos en el rango Q6:Y23
Los 6 cartones con sus números de bola se generan en el rango AB6:AJ23. Por ejemplo, la primera columna de cada cartón se genera con la fórmula matricial desbordada de la celda AB6:
=SI(Q6:Q23=0;"";INDICE(B$6:B$16;Q6:Q23))
Para saber cuando se extrae la bola con la que cantar los premios, en el rango AS5:ED5 hay una secuencia del 1 al 90, con las 90 extracciones posibles de todas las bolas.
Para saber cuantos números han salido en cada fila de cada cartón, se copia en el rango AS6:ED23 la siguiente fórmula, con la que se obtiene un valor entre 0 y 5 aciertos:
=SUMA(SI(SI.ERROR(COINCIDIR($AB6:$AJ6;BOLAS!$A$2:INDICE(BOLAS!$A$2#;AS$5);0);0)>0;1;0))
Para saber el número de bola que haría cantar ¡LÍNEA!, en cada fila de cada cartón, se hace arrastrando hacia abajo la fórmula de AN6, en el rango AN6:AN23:
=COINCIDIR(5;$AS6:$ED6;0)
Para saber el número de bola que haría cantar ¡DOS LÍNEAS! en cada cartón, se copia en cada 3 filas del rango AO6:AO23, la siguiente fórmula de AO6:
=SUMA($AN6:$AN8)-MAX($AN6:$AN8)-MIN($AN6:$AN8)
Para saber el número de bola que haría cantar ¡BINGO! en cada cartón, se copia en cada 3 filas del rango AP6:AP23, la siguiente fórmula de AP6:
=MAX($AN6:$AN8)
Los números de extracción con alguno de los 3 premios se calculan en el rango AN5:AP5, con la fórmula de AN5 copiada hacia la derecha:
=MIN(AN6:AN23)
Los números de bola con alguno de los 3 premios se calculan en el rango AN4:AP4, con la fórmula de AN4 copiada hacia la derecha:
=INDICE(BOLAS!$A$2#;AN5)
Los números de fila de la matriz de cartones con alguno de los 3 premios se calculan en el rango AN3:AP3, con la fórmula de AN3 copiada hacia la derecha:
=MIN(SI(misCartones=AN4;FILA(misCartones)))
Los números de cartón que han sido premiados se calculan en el rango AN2:AP2, con la fórmula de AN2 copiada hacia la derecha:
=COINCIDIRX(AN3-6;$N$6:$N$11;-1;1)
La información del rango AN2:AP5 se mostrará en la hoja 'BINGO' según se vayan extrayendo las bolas...
A este bingo iterativo se juega en la hoja 'BINGO'.
Con cálculo iterativo se obtiene la siguiente bola extraída en la celda Q2, con la fórmula:
=SI(BolaExtraer;MIN(CARTONES!$AP$5;BolaNúmero+1);0)
Siempre que sea VERDADERO la celda S2 con el nombre definido: BolaExtraer
Si ese nombre es FALSO, la celda S2 se pone a 0 y genera un nuevo juego de bolas y de cartones.
En el rango B3:J12 están las 90 bolas que, con un formato condicional, cambian de color si es la bola recién extraída o ya ha sido extraída. La fórmula matricial en B3 es:
=TRANSPONER(SECUENCIA(9;10))
Se indican las 3 bolas previas extraídas en el rango L5:L7, con la fórmula matricial en L5:
=SI(BolaNúmero<2;"";INDICE(misBolas;SI(BolaNúmero>3;BolaNúmero-3;SI(BolaNúmero>2;BolaNúmero-2;1))):INDICE(misBolas;SI(BolaNúmero>1;BolaNúmero-1;1)))
El último número de bola extraído se muestra en la celda combinada P6:R8, con la fórmula:
=SI(BolaNúmero=0;0;INDICE(BOLAS!$A$2#;BolaNúmero))
Los 3 premios aparecen en las siguientes celdas con sus fórmulas:
L13: =SI(BolaNúmero>=Q13;"¡LÍNEA!";"")
L14: =SI(BolaNúmero>=Q14;"¡DOS LÍNEAS!";"")
L15: =SI(BolaNúmero>=Q15;"¡BINGO!";"")
En la fila 16 hay 3 secuencias auxiliares del 1 al 9 para pintar los 6 cartones.
En la columna A hay 2 secuencias auxiliares del 1 al 3 para pintar los 6 cartones.
En 6 celdas concretas se indica qué cartón se pintará de los 6 cartones posibles:
A17: =CARTONES!$N$6
L17: =CARTONES!$N$7
W17: =CARTONES!$N$8
A22: =CARTONES!$N$9
L22: =CARTONES!$N$10
W22: =CARTONES!$N$11
Los números de bolas del cartón 1 se obtienen copiando en el rango B18:J20 la fórmula de la celda B18:
=INDICE(misCartones;$A$17+$A18;B$16)
Los números de bolas del cartón 2 se obtienen copiando en el rango M18:U20 la fórmula de la celda M18:
=INDICE(misCartones;$L$17+$A18;M$16)
Los números de bolas del cartón 3 se obtienen copiando en el rango X18:AF20 la fórmula de la celda X18:
=INDICE(misCartones;$W$17+$A18;X$16)
Los números de bolas del cartón 4 se obtienen copiando en el rango B23:J25 la fórmula de la celda B23:
=INDICE(misCartones;$A$22+$A23;B$16)
Los números de bolas del cartón 5 se obtienen copiando en el rango M23:U25 la fórmula de la celda M23:
=INDICE(misCartones;$L$22+$A23;M$16)
Los números de bolas del cartón 6 se obtienen copiando en el rango X23:AF25 la fórmula de la celda X23:
=INDICE(misCartones;$W$22+$A23;X$16)
¡Y eso es todo amigos!
¡Felices vacaciones de verano!
¡Hasta septiembre!
No Response to "Mi bingo iterativo"
Leave A Reply
Comenta este artículo, critícalo o avisa si detectas algún error que haya que corregir.