Hace 2 horas
Filtros de municipios españoles
Posted on enero 22, 2024 by Excel Pedro Wave
🔝To translate this blog post to your language, select it in the top left Google box.
Esta es la tercera entrega sobre mapas de municipios españoles, en el que he cambiado la forma de filtrarlos.
Su principal característica es que he quitado las segmentaciones de datos, que ocupaban mucho espacio, y las he sustituido por 3 filtros avanzados con validación de datos: Autonomías; Provincias y Municipios.
En los ejemplos de la imagen animada he filtrado por Municipios:
- Que comienzan por za
- Que contienen ona, con el carácter comodín asterisco: *ona
- Que comienzan por las *, con un espacio y un asterisco.
En los desplegables aparece la lista de municipios filtrados y ordenados.
Este modo de filtrado se aplica a los 3 filtros, no sólo a los Municipios sino a Provincias y a Autonomías.
Estos filtros no los he hecho con las nuevas funciones de la última versión de Excel, sino que he usado funciones de toda la vida, para que sigan siendo compatibles con versiones desde Excel 2010 en adelante.
En el vídeo explico cómo filtrar municipios y cómo abrir enlaces a Wikipedia, y así saber más de autonomías, provincias y municipios españoles.
Los nuevos filtros permiten filtrar por:
- Autonomías, en la celda U2 con el nombre definido: miAutonomía. Con una validación de datos en una lista desplegable con origen: =miRangoAutonomías
- Provincias, en la celda U4 con el nombre definido: miProvincia. Con una validación de datos en una lista desplegable con origen: =miRangoProvincias
- Municipios, en la celda U6 con el nombre definido: miMunicipio. Con una validación de datos en una lista desplegable con origen: =miRangoMunicipios
Las 3 validaciones de datos no generan ningún mensaje de error cuando se escribe texto que no está en la lista desplegable.
Para ello en la pestaña: Mensaje de error, no debe estar marcado: Mostrar mensaje de error si se introducen datos no válidos
Con lo que, por ejemplo se puede escribir: za; *ona; las *, o cualquier otra combinación de caracteres por la que se filtre por Autonomías, Provincias o Municipios.
En la búsqueda se pueden usar los caracteres comodín:
* asterisco para representar cualquier conjunto de caracteres.
? interrogante para representar un carácter cualquiera en esa posición.
~ tilde generado con la tecla Alt + 126 (código introducido con el teclado numérico) para poder buscar un carácter *, ? o tilde con: ~*. ~? o ~~
En esta página se explica el uso de los comodines:
En la hoja 'DATOS' se generan lo orígenes de las 3 validaciones de datos.
En el rango T:V se genera el origen de la validación de Autonomías, a partir de la columna H con las autonomías de la tabla dinámica.
Las autonomías no repetidas de la columna T se generan con la fórmula:
=SI.ERROR(INDICE($H$2:$H$8132;COINCIDIR(FILA($H$2:$H$8132)+1-FILA(INDICE($H$2:$H$8132;1));CONTAR.SI($H$2:$H$8132;"<="&INDICE(SI.ERROR($H$2:$H$8132&"";0);FILA($H$2:$H$8132)+1-FILA(INDICE($H$2:$H$8132;1))));0));"")
Las autonomías ordenadas de la columna U se generan con la fórmula:
=SI.ERROR(INDICE($T$2:$T$8132;K.ESIMO.MENOR(SI(SI.ERROR($T$2:$T$8132&"";"")="";"";COINCIDIR(FILA($T$2:$T$8132);FILA($T$2:$T$8132);0));FILA($T$2:$T$8132)+1-FILA(INDICE($T$2:$T$8132;1))))&"";"")
Las autonomías listadas de la columna V se generan con la fórmula:
=INDICE(DATOS!$U$2:$U$8132;1):INDICE(DATOS!$U$2:$U$8132;MAX(1;CONTAR.SI(DATOS!$U$2:$U$8132;"?*")))
En el rango X:Z se genera el origen de la validación de Provincias, a partir de la columna I con las provincias de la tabla dinámica.
Las provincias no repetidas de la columna X se generan con la fórmula:
=SI.ERROR(INDICE($I$2:$I$8132;COINCIDIR(FILA($I$2:$I$8132)+1-FILA(INDICE($I$2:$I$8132;1));CONTAR.SI($I$2:$I$8132;"<="&INDICE(SI.ERROR($I$2:$I$8132&"";0);FILA($I$2:$I$8132)+1-FILA(INDICE($I$2:$I$8132;1))));0));"")
Las provincias ordenadas de la columna Y se generan con la fórmula:
=SI.ERROR(INDICE($X$2:$X$8132;K.ESIMO.MENOR(SI(SI.ERROR($X$2:$X$8132&"";"")="";"";COINCIDIR(FILA($X$2:$X$8132);FILA($X$2:$X$8132);0));FILA($X$2:$X$8132)+1-FILA(INDICE($X$2:$X$8132;1))))&"";"")
Las provincias listadas de la columna Z se generan con la fórmula:
=INDICE(DATOS!$Y$2:$Y$8132;1):INDICE(DATOS!$Y$2:$Y$8132;MAX(1;CONTAR.SI(DATOS!$Y$2:$Y$8132;"?*")))
En el rango AB:AD se genera el origen de la validación de Municipios, a partir de la columna J con los municipios de la tabla dinámica.
Los municipios no repetidos de la columna AB se generan con la fórmula:
=SI.ERROR(INDICE($J$2:$J$8132;COINCIDIR(FILA($J$2:$J$8132)+1-FILA(INDICE($J$2:$J$8132;1));CONTAR.SI($J$2:$J$8132;"<="&INDICE(SI.ERROR($J$2:$J$8132&"";0);FILA($J$2:$J$8132)+1-FILA(INDICE($J$2:$J$8132;1))));0));"")
Los municipios ordenados de la columna AC se generan con la fórmula:
=SI.ERROR(INDICE($AB$2:$AB$8132;K.ESIMO.MENOR(SI(SI.ERROR($AB$2:$AB$8132&"";"")="";"";COINCIDIR(FILA($AB$2:$AB$8132);FILA($AB$2:$AB$8132);0));FILA($AB$2:$AB$8132)+1-FILA(INDICE($AB$2:$AB$8132;1))))&"";"")
Los municipios listados de la columna AD se generan con la fórmula:
=INDICE(DATOS!$AC$2:$AC$8132;1):INDICE(DATOS!$AC$2:$AC$8132;MAX(1;CONTAR.SI(DATOS!$AC$2:$AC$8132;"?*")))
Las columnas V, Z y AD no son estrictamente necesarias, únicamente están para que quede más claro que se consiguen rango de datos con exactamente el listado de autonomías, provincias y municipios.
Donde si que son necesarias las fórmulas de esas 3 columnas es en estos nombres definidos:
- miRangoAutonomías como origen de la validación de autonomías.
- miRangoProvincias como origen de la validación de provincias.
- miRangoMunicipios como origen de la validación de municipios.
En esta imagen se muestran los orígenes de los 3 filtros de nombres definidos.
Como un plus para hacer este mapa más interesante he añadido 3 enlaces a Wikipedia, para saber más sobre autonomías, provincias y municipios.
Una vez seleccionado un municipio en el mapa con el ratón, en las celdas U14, U15 y U16 se crean hipervínculos a Wikipedia para esos datos con las fórmulas:
Municipio en U14:
=HIPERVINCULO("https://es.wikipedia.org/wiki/" & SI.ERROR(EXTRAE(INDICE(DATOS!$J$2:$J$8132;miPunto)&"";ENCONTRAR("/";INDICE(DATOS!$J$2:$J$8132;miPunto)&"")+1;50);INDICE(DATOS!$J$2:$J$8132;miPunto)&"");INDICE(DATOS!$J$2:$J$8132;miPunto)&"")
Provincia en U15:
=HIPERVINCULO("https://es.wikipedia.org/wiki/provincia_de_" & SI.ERROR(EXTRAE(INDICE(DATOS!$I$2:$I$8132;miPunto)&"";ENCONTRAR("/";INDICE(DATOS!$I$2:$I$8132;miPunto)&"")+1;50);INDICE(DATOS!$I$2:$I$8132;miPunto)&"");INDICE(DATOS!$I$2:$I$8132;miPunto)&"")
Autonomía en U16:
=HIPERVINCULO("https://es.wikipedia.org/wiki/" & IZQUIERDA(INDICE(DATOS!$H$2:$H$8132;miPunto)&"";SI.ERROR(ENCONTRAR("/";INDICE(DATOS!$H$2:$H$8132;miPunto)&"")-1;LARGO(INDICE(DATOS!$H$2:$H$8132;miPunto)&"")));INDICE(DATOS!$H$2:$H$8132;miPunto)&"")
Este mapa con filtros de municipios españoles es compatible con todas las versiones de escritorio, desde Excel 2010 hasta Excel para Microsoft 365.
Descarga la versión 1.0 desde uno de estos enlaces:
- Microsoft OneDrive: Filtros de municipios españoles - PW1.xlsm
- Sites Google Drive: Filtros de municipios españoles - PW1.xlsm
Las macros del archivo descargado están bloqueadas por defecto. Para desbloquear las macros debes modificar las Propiedades del archivo siguiendo estas instrucciones:
Las macros de Internet están bloqueadas de forma predeterminada en Office - Deploy Office | Microsoft Learn
Abre el archivo y presiona el botón: Habilitar edición cuando aparezca el aviso de VISTA PROTEGIDA.
Presiona el botón: Habilitar contenido cuando aparezca la ADVERTENCIA DE SEGURIDAD Las macros se han deshabilitado o se deshabilitó parte del contenido activo.
Las hojas están protegidas sin contraseña y no está protegido el proyecto VBA, por lo que puedes estudiar y analizar el código de las macros.
ATENCIÓN: Se puede modificar este libro de Excel respetando esta licencia:
Creative Commons — Atribución-NoComercial-CompartirIgual-No portada — CC BY-NC-SA 4.0
En este enlace están todas las entregas dedicadas a los municipios españoles que he escrito hasta ahora:
En la próxima entrega pensaré en cómo controlar los municipios españoles al cambiar el zoom para no perder el foco.
Suscribirse a:
Enviar comentarios (Atom)
Mi lista de blogs
-
Nuevo mapa de municipios - Domadores - 🔝*To translate this blog post to your language, select it in the top left Google box. * *A partir de ahora aprenderás a domar fieras 🐈⬛ 🐘 🐯 🦁 🐍...
-
More on TrimRange and the Drop Function - A comment on my previous post links to a helpful YouTube video on using TrimRange and the Dot operator: It also looks at using the Drop Function to exclude...Hace 3 días
-
FLUJO DE AUTOMATE CON IA PARA GENERAR FELICITACIONES DE CUMPLEAÑOS - Hola a todos, Os imagináis una felicitación de cumpleaños así?: y que además una gran parte de su contenido está generado con IA, en concreto … La entra...Hace 4 días
-
5 maneras de trabajar con más de millón de filas en Excel - Seguramente alguien ya te dijo —o te va a decir— que “Excel no puede trabajar con archivos grandes”.Y sí, Excel […] The post 5 maneras de trabajar con má...Hace 6 días
-
¿Cuánto sabes de Tablas dinámicas Excel? ¡Pon a prueba tus conocimientos! - Excel es mucho más que hojas de cálculo, sabes de Tablas dinámicas Excel. Entonces sabes que es una herramienta que te ayuda a tomar decisiones, automati...Hace 1 semana
-
25 Years of Contextures – 40 Years of Excel - Twenty-five years ago, on November 15, 2000, I registered and launched my Contextures.com website. It had a few Excel tutorials, and a small selection of s...Hace 1 semana
-
Polidivisibles - Un número se llama polidivisible (aquí se limitará el estudio a base 10) cuando al recorrer sus cifras de izquierda a derecha, las dos primeras forman un...
Hace 1 semana -
Excel para Calcular la Capacidad de Carga del Suelo – Método de Terzaghi - La capacidad de carga del suelo es un parámetro fundamental en el diseño de cimentaciones, ya que determina la máxima presión que el terreno puede soportar...
Hace 1 semana -
How to Use the COPILOT Function in Microsoft Excel - Wondering if you could use the mighty Copilot AI from Microsoft in your Excel workbooks to think and work faster? I’ve got you covered! Read on to learn ho...Hace 2 semanas
-
Mostrar datos de dos celdas en un cuadro de texto de Microsoft Excel - En Microsoft Excel es posible vincular el contenido de una celda a un cuadro de texto o a una forma. Vincular contenido de cuadro de texto a valor de cel...Hace 3 semanas
No Response to "Filtros de municipios españoles"
Leave A Reply
Comenta este artículo, critícalo o avisa si detectas algún error que haya que corregir.